home *** CD-ROM | disk | FTP | other *** search
/ SGI Hot Mix 17 / Hot Mix 17.iso / HM17_SGI / research / examples / demo / demosrc / d_wavelet.pro < prev    next >
Encoding:
Text File  |  1997-07-08  |  49.2 KB  |  1,538 lines
  1. ;$Id: d_wavelet.pro,v 1.23 1997/04/25 22:19:33 tremblay Exp $
  2. ;
  3. ;  Copyright (c) 1997, Research Systems, Inc. All rights reserved.
  4. ;       Unauthorized reproduction prohibited.
  5. ;
  6. ;+
  7. ;  FILE:
  8. ;       d_wavelet.pro
  9. ;
  10. ;  CALLING SEQUENCE: d_wavelet
  11. ;
  12. ;  PURPOSE:
  13. ;       This example demonstrates the wavelets orthogonal functions
  14. ;
  15. ;  MAJOR TOPICS: Plotting and data analysis
  16. ;
  17. ;  CATEGORY:
  18. ;       IDL 5.0
  19. ;
  20. ;  INTERNAL FUNCTIONS and PROCEDURES:
  21. ;       fun wv_cutoff               -  Returns a threshold value
  22. ;       fun decimate                -  Set values within threshold limits
  23. ;       pro get_wavelet_basis       -  Compute the wavelet basis
  24. ;       fun adjust_size             -  Adjust data size
  25. ;       fun in_range                -  Set values within a give n range
  26. ;       pro no_compressed_image     -  Handle the no compressed image state
  27. ;       pro reset_plot              -  Reset the plots
  28. ;       pro Update_plot             -  Redraw the plots
  29. ;       pro new_percentage          -  Set to a new percentage (slider)
  30. ;       pro move_line               -  Move the plot line
  31. ;       pro moveSlider              -  Update slider value
  32. ;       pro got_new_image           -  Display the image
  33. ;       pro sensitize               -  Sensitize a widget
  34. ;       pro ChangeFilename          -  Update the title
  35. ;       pro erase_original          -  Erase the original image
  36. ;       pro erase_secondary         -  Erase the secondary image
  37. ;       pro data_input              -  Load a new data set
  38. ;       pro do_compression          -  Compute and display the compressed image
  39. ;       pro new_coeff               -  Handle the new coefficients
  40. ;       pro waveletTool_Event       -  Event handler
  41. ;       pro wavelet_Cleanup         -  Cleanup
  42. ;       pro d_wavelet                 -  Main procedure
  43. ;
  44. ;  EXTERNAL FUNCTIONS, PROCEDURES, and FILES:
  45. ;       pro getdata2                -  Read new data
  46. ;       wavelet.txt
  47. ;       wavelet.tip
  48. ;       abnorm1.dat
  49. ;       convec.dat
  50. ;       ctscan.dat
  51. ;       head.dat
  52. ;       hurric.dat
  53. ;       m51.dat
  54. ;       nyny.dat
  55. ;       sunflare.dat
  56. ;       venus_1.dat
  57. ;       venus_2.dat
  58. ;       venus_e.dat
  59. ;       worldelv.dat
  60. ;
  61. ;  REFERENCE: IDL Reference Guide, IDL User's Guide
  62. ;
  63. ;  NAMED STRUCTURES:
  64. ;       none.
  65. ;
  66. ;  COMMON BLOCS:
  67. ;       none.
  68. ;
  69. ;  MODIFICATION HISTORY:
  70. ;       95,   DS   - Written.
  71. ;       11/95,   DAT     - Modified for IDL 5.0 demo
  72. ;-
  73. ;---------------------------------------------------------------------  
  74. ;
  75. ;  PURPOSE
  76. ;       Return array of threshold value versus (% decimation * 10.)
  77. ;       For example, to get cutoff value for decimation of 60%,
  78. ;    use cutoff(60 * 10).
  79. ; Inputs:
  80. ;    Wavelet = array containing wavelet transform.
  81. ; Outputs:
  82. ;    Wvlog = log10 of wavelet transform (elements less than 10^(-4)
  83. ;        are set to 10^(-4).
  84. ;    Cutoff = 1001 element array containing threshold value versus
  85. ;        % decimation.
  86. ;
  87. ; 
  88.  
  89. ;+
  90. ; NAME:
  91. ;    GetData2
  92. ; PURPOSE:
  93. ;    Retrieves a data file from the images directory in the main IDL
  94. ;    directory.  The file can be specified when calling the routine
  95. ;    or the file can be chosen by the user with a widget that lets them
  96. ;    make the selection.
  97. ; CATEGORY:
  98. ;    Widgets
  99. ; CALLING SEQUENCE:
  100. ;    GetData2, NEWDATA
  101. ; KEYWORD PARAMETERS:
  102. ;    ASSOC_IT = When set, this keyword forces the routine to return
  103. ;        an associated variable instead of a standard IDL variable.  
  104. ;        This is more efficient when loading animations for instance
  105. ;        as it removes the need to create two copies of the data
  106. ;        in memory (one for the animation, one for the load data).
  107. ;    DESCRIPTION = This keyword returns the description of the data
  108. ;        selected by the GetData routine (NEWDATA).
  109. ;    DIMENSIONS = This keyword returns the dimensions of the data
  110. ;        selected by the GetData routine.  These dimensions 
  111. ;        are the dimensions of the NEWDATA variable.
  112. ;    FILENAME = The name of the file that is to be selected from the
  113. ;        images subdirectory.  If this keyword is set, no user 
  114. ;        selection widget is created.
  115. ;    OFILENAME = name of file selected.
  116. ;    ONE_DIM = This keyword is set when the routine is to consider
  117. ;        one dimensional data from the data contained in the
  118. ;        images subdirectory.
  119. ;    TWO_DIM = This keyword is set when the routine is to consider
  120. ;        two dimensional data from the data contained in the
  121. ;        images subdirectory.  When searching for two dimensional
  122. ;        data, this routine will use the first slice of any 
  123. ;        three dimensional data that it encounters.
  124. ;    THREE_DIM = This keyword is set when the routine is to consider
  125. ;        three dimensional data from the data contained in the
  126. ;        images subdirectory.
  127. ;    TITLE = The string that will appear in the title portion
  128. ;        of the data selection widget.  If not specified, the
  129. ;        title will be "Please Select Data".
  130. ; OUTPUTS:
  131. ;    NEWDATA = the variable that is to be filled with the new data.
  132. ; COMMON BLOCKS:
  133. ;    GF - maintains which selection was made when using the data
  134. ;        selection widget.
  135. ; SIDE EFFECTS:
  136. ;    Desensitizes all the other widgets and is modal in behavior.  It 
  137. ;    forces the user to make a selection before proceeding with other 
  138. ;    widget functions.
  139. ; RESTRICTIONS:
  140. ;    Getdat2 must find the subdirectory called examples/dataimages of
  141. ;       the main IDL directory(IDL_DIR) and the directory must contain a
  142. ;       file called data.txt that describes the contents of the directory.
  143. ; PROCEDURE:
  144. ;    If the FILENAME keyword was not set, determine the file name using
  145. ;    a widget that lets the user make a selection from the data.txt file
  146. ;    and then open that file, read the data, dimensions, and description,
  147. ;    and return the data.
  148. ; MODIFICATION HISTORY:
  149. ;    Written by Steve Richards,    Dec, 1990
  150. ;       Modified by DAT, renamed getData2, add group keyword, 2/97
  151. ;-
  152. ;---------------------------------------------------------------------
  153. ;
  154. ;  PURPOSE  : Event handler
  155. ;
  156. pro GetData2_event, $
  157.     event              ; IN: event structure.
  158.  
  159.     COMMON GF, selection
  160.  
  161.     WIDGET_CONTROL, event.id, GET_UVALUE=selected
  162.  
  163.     case selected of
  164.         "FILELST": begin
  165.         WIDGET_CONTROL, event.top, SENSITIVE=0
  166.         WIDGET_CONTROL, event.top, /DESTROY
  167.         selection = event.index + 1
  168.         end    ;  of FILELST
  169.  
  170.         "CANCEL": WIDGET_CONTROL, event.top, /DESTROY
  171.     endcase
  172.  
  173. end    ;   of GetData_event 
  174.  
  175.  
  176. ;---------------------------------------------------------------------
  177. ;
  178. ;  PURPOSE  : Main procedure.
  179. ;    Retrieves a data file from the images directory in the main IDL
  180. ;    directory.  The file can be specified when calling the routine
  181. ;    or the file can be chosen by the user with a widget that lets them
  182. ;    make the selection.
  183. ;
  184. pro GetData2, $
  185.     NEWDATA, $                    ; OUT: new data set
  186.     GROUP=group, $                ; IN: (opt) group leader identifer.
  187.     DESCRIPTION = DESCRIPTION, $  ; OUT:  (opt)Data set description.
  188.     DIMENSIONS = DIMENSIONS, $    ; OUT: (opt) dimension of the data set
  189.     ONE_DIM = ONE_DIM, $          ; IN: (opt) Routine will consider 1-D data.
  190.     TWO_DIM = TWO_DIM, $          ; IN: (opt) Routine will consider 2-D data.
  191.     THREE_DIM = THREE_DIM, $      ; IN: (opt) Routine will consider 3-D data.
  192.     TITLE = TITLE, $              ; IN: (opt) Selection window title.
  193.     FILENAME = FILENAME, $        ; IN: File name of the data set.
  194.     OFILENAME = OFILENAME, $      ; OUT: (opt) output file name.
  195.     ASSOC_IT = ASSOC_IT           ; IN: (opt) routine returns an associate 
  196.                                   ;     variable instead of IDL variable. 
  197.  
  198.     COMMON GF, selection
  199.  
  200.     ;  For demo 5, the image files are located in the same directory
  201.     ;  tnan this procedure. Therefore, the data path is set to ' ' .
  202.     ;
  203.     datapath = filepath('', SUBDIR=['examples','data'])
  204.  
  205.     ;  Initialize working variables.
  206.     ;
  207.     name = ''
  208.     dim = LONARR(3)
  209.     des = ''
  210.     del = ''
  211.     numfiles = 0L
  212.     ONE_MASK = 1
  213.     TWO_MASK = 2
  214.     THREE_MASK = 4
  215.  
  216.     NEWDATA = 0
  217.     DESCRIPTION = 0
  218.     DIMENSIONS = 0
  219.  
  220.     if (KEYWORD_SET(FILENAME)) then begin
  221.         OPENR, unit, datapath + "data.txt", /GET_LUN
  222.         READF, unit, numfiles
  223.         if (numfiles NE 0) then begin
  224.             goodindex = 0
  225.             nameindex = 0
  226.  
  227.             while((nameindex LT (numfiles)) AND (goodindex EQ 0)) do begin
  228.                 READF, unit, name, dim, des, del
  229.                 if (name EQ FILENAME) then goodindex = 1
  230.                 if (del NE '*') then MESSAGE, $
  231.                     "* delimiter not found in data.txt"
  232.             endwhile
  233.  
  234.             FREE_LUN, unit
  235.  
  236.             if (goodindex NE 0) then begin
  237.             ofilename = filename
  238.                 OPENR, unit, datapath + FILENAME, /GET_LUN, /BLOCK
  239.  
  240.                 if (KEYWORD_SET(ASSOC_IT)) then begin
  241.                 NEWDATA = ASSOC(unit, BYTARR(dim(0),dim(1)))
  242.                 endif else begin
  243.                 NEWDATA = bytarr(dim(0), dim(1), dim(2))
  244.                 READU, unit, NEWDATA
  245.                     FREE_LUN, unit
  246.                 endelse
  247.  
  248.                 DESCRIPTION = des
  249.                 DIMENSIONS = dim
  250.             endif
  251.         endif
  252.     endif else if ((XRegistered("GetData2") EQ 0)) then begin
  253.  
  254.         FILTER = 0
  255.  
  256.         if (KEYWORD_SET(ONE_DIM)) then begin
  257.             FILTER = FILTER OR ONE_MASK
  258.         endif
  259.  
  260.         if (KEYWORD_SET(TWO_DIM)) then begin
  261.             FILTER = FILTER OR TWO_MASK OR THREE_MASK
  262.         endif
  263.  
  264.         if (KEYWORD_SET(THREE_DIM)) then begin
  265.             FILTER = FILTER OR THREE_MASK
  266.         endif
  267.  
  268.         if ((FILTER EQ 0)) then begin
  269.             FILTER = ONE_MASK + TWO_MASK + THREE_MASK
  270.         endif
  271.  
  272.         OPENR, unit, datapath + "data.txt", /GET_LUN
  273.         READF, unit, numfiles
  274.         if (numfiles NE 0) then begin
  275.             names = STRARR(numfiles)
  276.             descriptions = STRARR(numfiles)
  277.             dimensions = LONARR(3,numfiles)
  278.             goodindex = 0
  279.  
  280.             for nameindex = 0, numfiles - 1 do begin
  281.                 READF, unit, name, dim, des, del
  282.                 TEMPFILT = 0
  283.                 if (DIM(0) GT 1) then  TEMPFILT = ONE_MASK
  284.                 if (DIM(1) GT 1) then  TEMPFILT = TWO_MASK
  285.                 if (DIM(2) GT 1) then  TEMPFILT = THREE_MASK
  286.  
  287.                 if ((TEMPFILT AND FILTER) NE 0) then begin
  288.                     names(goodindex) = name
  289.                     dimensions(*,goodindex) = dim
  290.                     descriptions(goodindex) = des
  291.                     goodindex = goodindex + 1
  292.                 endif
  293.  
  294.                 if (del NE '*') then begin
  295.                     MESSAGE, "* delimiter not found in data.txt"
  296.                 endif
  297.  
  298.             endfor
  299.  
  300.             FREE_LUN, unit
  301.  
  302.             neworder = SORT(names(0:goodindex-1))
  303.             names = names(neworder)
  304.             descriptions = descriptions(neworder)
  305.             dimensions = dimensions(*,neworder)
  306.  
  307.             filler = "........................................"
  308.             fullnames = STRARR(goodindex)
  309.  
  310.             for i = 0, goodindex - 1 do begin
  311.                 dimstring = STRING(dimensions(*,i), $
  312.                     FORMAT = '("[",I0.3,", ",I0.3,", ",I0.3,"]")')
  313.                 length = STRLEN(names(i))
  314.                 lengthdim = STRLEN(dimstring)
  315.                 fullnames(i) = descriptions(i)
  316. ;      fullnames(i) = names(i) + $
  317. ;        STRMID(filler, 0, 30-length) + $
  318. ;        dimstring + $
  319. ;        STRMID(filler, 0, 30-lengthdim) + $
  320. ;        descriptions(i)
  321.             endfor
  322.  
  323.             if (NOT(KEYWORD_SET(TITLE))) then TITLE =  "Please Select Data"
  324.  
  325. ;    font = '*fixed*'   ;It seems to be impossible to find
  326. ;        a simple font on all servers.
  327.  
  328.             if (NOT(KEYWORD_SET(group))) then begin
  329.  
  330.                 loadbase = WIDGET_BASE(TITLE = TITLE, $
  331.                     /COLUMN, $
  332.                     XPAD = 50, $
  333.                     YPAD = 50, $
  334.                     SPACE = 20)
  335.             endif else begin
  336.                 loadbase = WIDGET_BASE(TITLE = TITLE, $
  337.                     GROUP_LEADER=group, /MODAL, $
  338.                     /COLUMN, $
  339.                     XPAD = 50, $
  340.                     YPAD = 50, $
  341.                     SPACE = 20)
  342.             endelse
  343.  
  344.                 loadbox = WIDGET_BASE(loadbase, $
  345.                     /COLUMN, $
  346.                     /FRAME, $
  347.                     SPACE=10)
  348.  
  349.                     loadlist = WIDGET_LIST(loadbox, $
  350.                         VALUE=fullnames, $
  351.                         UVALUE="FILELST", $
  352.                         YSIZE=10)
  353.  
  354.                 loadcancel = WIDGET_BUTTON(loadbase, $
  355.                     VALUE="Cancel", UVALUE="CANCEL")
  356.  
  357.         WIDGET_CONTROL, loadbase, /REALIZE
  358.   
  359.         selection = 0
  360.     
  361.         XMANAGER, "GetData2", loadbase 
  362.  
  363.         if (selection NE 0) then begin
  364.  
  365.             if ((NOT(KEYWORD_SET(THREE_DIM))) AND $
  366.                 (dimensions(2,selection-1) NE 1)) then $
  367.                 dimensions(2,selection-1) = 1
  368.  
  369.                 OPENR, unit, datapath + $
  370.                     names(selection - 1), /GET_LUN, /BLOCK
  371.                 ofilename = names(selection - 1)
  372.  
  373.                 if (KEYWORD_SET(ASSOC_IT))  then begin
  374.                 NEWDATA = ASSOC(unit, $
  375.                         BYTARR(dimensions(0, selection-1), $
  376.                         dimensions(1, selection-1)))
  377.                 endif else begin
  378.                 NEWDATA = BYTARR(dimensions(0, selection - 1), $
  379.                         dimensions(1, selection - 1), $
  380.                         dimensions(2, selection - 1))
  381.                 READU, unit, NEWDATA
  382.                 FREE_LUN, unit
  383.                 endelse
  384.  
  385.                 DESCRIPTION = descriptions(selection - 1)
  386.                 DIMENSIONS = dimensions(*,selection - 1)
  387.  
  388.             endif    ;  of keyword set three_dim
  389.         endif     ;   of selection NE 0
  390.     endif     ;  of keyword set filename.
  391.  
  392. end           ;  of GETDATA2
  393.  
  394.  
  395. ;---------------------------------------------------------------------
  396. ;
  397. ;  PURPOSE  : Compute the cutoff paramater.
  398. ;
  399. function WV_CUTOFF, $
  400.     wavelet         ; IN: wavelet coefficients.
  401.  
  402.     lowthr = 4         ; Consider only values over 10-lowthr
  403.     nhist = 1000     ; Number of histogram bins
  404.     nbins = 1000     ; Number of returned bins
  405.  
  406.     wvlog = alog10(abs(wavelet) > (10.0^(-lowthr))) + lowthr
  407.     wlmin = min(wvlog, MAX = wlmax)
  408.     bins = (wlmax - wlmin) / nhist
  409.     h = histogram(wvlog, min = wlmin, max = wlmax, binsize = bins) / $
  410.     float(n_elements(wvlog))
  411.     for i=1, nhist-1 do h(i) = h(i) + h(i-1)    ;Cumulative integral
  412.  
  413.     ;  This plus 1 for maximum value.
  414.     ;
  415.     cutoff = FLTARR(nbins+1)
  416.     j = 0
  417.     for i=1, nbins-1 do begin
  418.         t = float(i) / nbins
  419.         while (h(j) lt t) and (j lt nhist) do j = j + 1
  420.         cutoff(i) = j
  421.     endfor
  422.     cutoff = 10.0 ^ (cutoff * (wlmax/nhist) - lowthr)
  423.  
  424.     ;  Cutoff 1000 must hold the max value of the array
  425.     ;
  426.     cutoff(1000) = max(abs(wavelet))
  427.  
  428.     RETURN, cutoff
  429.  
  430. end
  431.  
  432. ;---------------------------------------------------------------------  
  433. ;
  434. ;   PURPOSE : Set the data to zero when below threshold value.
  435. ;
  436. function DECIMATE, original, threshold
  437.         new = original
  438.     d = where(abs(new) le threshold, count)     
  439.  
  440.     ;  If d=-1 then there is noplace like that   
  441.     ;
  442.     if (count GT 0) then new(d) = 0.0     
  443.     return, new
  444. end
  445.  
  446. ;---------------------------------------------------------------------  
  447. ;
  448. ;   PURPOSE : Clamp and scale input data and then display.
  449. ;             Assumes display is set to desired window
  450. ;
  451. pro demo_wvlt_tv, input
  452.     input = input > 0
  453.     input = input < 255
  454.     TVSCL, input
  455. end     
  456. ;---------------------------------------------------------------------  
  457. ;
  458. ;   PURPOSE : Compute the wavelet basis.
  459. ;
  460. pro Get_Wavelet_Basis, $
  461.     UVAL     ; IN: uval structure     
  462.  
  463.     ;  Given our uncompressed array     
  464.     ;  and coefficients, get a new     
  465.     ;  wavelet basis for the image     
  466.     ;
  467.     WIDGET_CONTROL, /HOURGLASS
  468.     UVAL.WVLT_IMG = NR_WTN(UVAL.ORIG_IMG, UVAL.COEFFS)
  469.   
  470.     UVAL.THRESHARRAY = WV_CUTOFF(UVAL.WVLT_IMG)
  471.  
  472.     ;  Now we need to tv the image of the
  473.     ;  undecimated and decimated wavelet bases
  474.     ;
  475.     WSET, UVAL.ID_WAVE1
  476.     demo_wvlt_tv, CONGRID (UVAL.WVLT_IMG, 200, 200)
  477.           
  478.     ;  Now we need to create the new plot
  479.     ;
  480.     Percent_Plot, UVAL
  481.     Reset_Plot, UVAL
  482. end     
  483.  
  484. ;---------------------------------------------------------------------  
  485. ;
  486. ;   PURPOSE : Adjust the viewwing area size.
  487. ;
  488. function Adjust_Size, $
  489.     Orig_Image       ; IN: original image   
  490.      
  491.     s = SIZE(Orig_Image)     
  492.              
  493.     if ((s(1) EQ 256) AND (s(2) EQ 256)) then begin
  494.         New_Image = Orig_Image     
  495.     endif else begin
  496.         New_Image = CONGRID (Orig_Image, 256, 256, /INTERP)     
  497.     endelse
  498.                      
  499.     RETURN, New_Image     
  500. end     
  501.  
  502. ;---------------------------------------------------------------------  
  503. ;
  504. ;   PURPOSE : Make the data to fall within a range
  505. ;
  506. function IN_RANGE, $
  507.     VALUE, $    ; IN: data
  508.     MINVAL, $   ; IN: minimum value
  509.     MAXVAL      ; IN: maximum value
  510.  
  511.     tmp = VALUE
  512.  
  513.     if (tmp LT MINVAL) then $
  514.         tmp = MINVAL $
  515.     ELSE if (tmp GT MAXVAL) then tmp = MAXVAL
  516.  
  517.     return, tmp
  518. end
  519.  
  520. ;---------------------------------------------------------------------  
  521. ;
  522. ;   PURPOSE :  This procedure clears the compressed image
  523. ;              and erase an image if appropriate.
  524. ;
  525. pro No_Compressed_Image, UVAL
  526.  
  527.     ;  This procedure clears the compressed image
  528.     ;  and erase an image if appropriate.
  529.     ;
  530.     if (UVAL.COMPRESSED EQ 1B) then begin
  531.     WSET, UVAL.ID_COMP
  532.     erase
  533.     ; do X plot
  534.     plots, [0,255],[0,255],/DEVICE
  535.     plots, [0,255],[255,0],/DEVICE
  536.     UVAL.COMP_IMG=0
  537.     empty
  538.         if NOT(Widget_Info(UVAL.WID_DIFFBASE, /Valid_Id)) then begin
  539.             B_DIFF = WIDGET_BASE(GROUP_LEADER=UVAL.WID_MAIN, $     
  540.                 COLUMN=1, MAP=0, $     
  541.                 TITLE='WaveletTool Image Differences')
  542.  
  543.                 D_DIFF = WIDGET_DRAW( B_DIFF, $     
  544.                     RETAIN=2, XSIZE=256, YSIZE=256, /FRAME)   
  545.  
  546.             WIDGET_CONTROL, B_DIFF, /Realize
  547.             WIDGET_CONTROL, D_DIFF, get_value=NEW_DIFF_ID
  548.             UVAL.ID_DIFF = NEW_DIFF_ID
  549.             UVAL.WID_DIFFBASE = B_DIFF
  550.         endif
  551.             WSET, UVAL.ID_DIFF
  552.         erase
  553.  
  554.         ; do X plot
  555.         plots, [0,255],[0,255],/DEVICE
  556.         plots, [0,255],[255,0],/DEVICE
  557.         empty
  558.         UVAL.COMPRESSED = 0B
  559.     endif    
  560. end
  561.  
  562. ;---------------------------------------------------------------------  
  563. ;
  564. ;   PURPOSE : Reset (empty) the drawing plots.
  565. ;
  566. pro Reset_Plot, $
  567.     UVAL    ; IN: uval structure
  568.  
  569.     ;  Reset plots.
  570.     ;
  571.     New_Percentage, UVAL, 0.0
  572.     Move_Line, UVAL, 0.0
  573. end
  574.  
  575. ;---------------------------------------------------------------------  
  576. ;
  577. ;   PURPOSE :  Refresh is set to 0/1 depending on whether we simply 
  578. ;              want to refresh the data in the plot.
  579. ;
  580. pro Percent_Plot, $
  581.     UVAL    ; IN: uval structure
  582.  
  583.     WSET, UVAL.ID_PLOT
  584.     plot_io, FINDGEN(1000)/10, UVAL.THRESHARRAY, $
  585.         ytitle='Threshold', $
  586.     Xtitle='% compression', YCHARSIZE=UVAL.CHARSIZE, $
  587.         XCHARSIZE=UVAL.CHARSIZE
  588. end
  589.  
  590. ;---------------------------------------------------------------------  
  591. ;
  592. ;   PURPOSE :  Update the compression plot.
  593. ;
  594. pro Update_Plot, $
  595.     UVAL    ; IN: uval structure
  596.  
  597.     ;  Refresh is set to 0/1 depending on whether we simply 
  598.     ;  want to refresh the data in the plot
  599.     ;
  600.     WSET, UVAL.ID_PLOT
  601.     PLOT_IO, FINDGEN(1000)/10, UVAL.THRESHARRAY, YTITLE='Threshold', $
  602.     XTITLE='% compression', $
  603.         /NOERASE, YCHARSIZE=UVAL.CHARSIZE, $
  604.         XCHARSIZE=UVAL.CHARSIZE
  605.  
  606. end
  607.  
  608. ;---------------------------------------------------------------------  
  609. ;
  610. ;   PURPOSE : Adjust the plot and slider to the new percentage value.
  611. ;
  612. pro New_Percentage, $
  613.     UVAL , $    ; IN: uval structure
  614.     PERCENT     ; IN: precentage value
  615.  
  616.     WIDGET_CONTROL,/hourglass
  617.     
  618.     ;  Send a 1 to move_line to refresh plot b/t draws.
  619.     ;
  620.     UVAL.PERCENTAGE = PERCENT
  621.  
  622.     ;  Get the appropriate threshold and save it
  623.     ;  (from the plotted dataset!).
  624.     ;
  625.     UVAL.THRESHOLD = UVAL.THRESHARRAY (UVAL.PERCENTAGE * 10)
  626.     Move_Slider, UVAL
  627.     textChange = ['void','comp1', 'comp2']
  628.     putTips, UVAL.sText, UVAL.wText[1], $
  629.         textChange, [0,1,2]
  630.     Update_Plot, UVAL        
  631.  
  632.     ;  Then it decimates and displays the new image 
  633.     ;  into the decimated wavelet draw widget.
  634.     ;
  635.     WSET, UVAL.ID_WAVE2
  636.     demo_wvlt_tv, CONGRID (Decimate(UVAL.WVLT_IMG, UVAL.THRESHOLD), 200, 200)
  637.     textChange = ['selecto','adjus', 'perce']
  638.     putTips, UVAL.sText, UVAL.wText[1], $
  639.         textChange, [0,1,2]
  640.  
  641. end
  642.  
  643. ;---------------------------------------------------------------------  
  644. ;
  645. ;   PURPOSE : Redraw the vertical line of the compression plot.
  646. ;
  647. pro Move_Line, $
  648.     UVAL , $    ; IN: uval structure
  649.     X           ; IN: precentage value
  650.  
  651.     ;  Expects X in DATA coordinates.
  652.     ;
  653.     WSET, UVAL.ID_PLOT
  654.     device, SET_GRAPHICS_FUNCTION=6
  655.     plots, [UVAL.PERCENTAGE, UVAL.PERCENTAGE],[1e-10, 1e+10], $
  656.         NOCLIP=0, /DATA, COLOR=200
  657.     empty
  658.     plots, [X,X],[1e-10, 1e+10], NOCLIP=0, /DATA, COLOR=200
  659.     device, SET_GRAPHICS_FUNCTION=3
  660.     xValue = STRING(UVAL.percentage, FORMAT='(f6.2)')
  661.     xValue = STRTRIM(xValue,2)
  662.     xValue = xValue + ' %'
  663.     WIDGET_CONTROL, UVAL.SliderValue, SET_VALUE=xValue
  664.     empty
  665.  
  666. end
  667.  
  668. ;---------------------------------------------------------------------  
  669. ;
  670. ;   PURPOSE : Update the slider to the new percentage value.
  671. ;
  672. pro Move_Slider, $
  673.     UVAL     ; IN: uval structure
  674.  
  675.     WIDGET_CONTROL, UVAL.WID_SLIDER, SET_VALUE=UVAL.PERCENTAGE
  676. end
  677.  
  678. ;---------------------------------------------------------------------  
  679. ;
  680. ;   PURPOSE :  Redo plots with new image.
  681. ;
  682. PRO Got_New_Image, $
  683.     UVAL     ; IN: uval structure
  684.  
  685.     ;  Display it.     
  686.     ;
  687.     textChange = ['void','comp1', 'comp2']
  688.     putTips, UVAL.sText, UVAL.wText[1], $
  689.         textChange, [0,1,2]
  690.     WSET, UVAL.ID_ORIG     
  691.     TVSCL, UVAL.ORIG_IMG     
  692.  
  693.     ;  Get wavelet basis for this image     .
  694.     ;
  695.     Get_Wavelet_Basis, UVAL     
  696.     textChange = ['selecto','adjus', 'perce']
  697.     putTips, UVAL.sText, UVAL.wText[1], $
  698.         textChange, [0,1,2]
  699.     WIDGET_CONTROL, UVAL.SliderValue, SET_VALUE=' 75.00%'
  700. end     
  701.      
  702. ;---------------------------------------------------------------------  
  703. ;
  704. ;   PURPOSE :  Redo plots with new image.
  705. ;
  706. pro Sensitize, $
  707.     UVAL, $     ; IN: uval structure
  708.     SENSE       ; IN: sensitive case (0 or 1)
  709.  
  710.     ;  Using ENABLE_WIDS, sensitize/desensitize
  711.     ;  the appropriate widgets.
  712.     ;
  713.     for i=0,(N_ELEMENTS(UVAL.ENABLE_WIDS)-1) do $
  714.         WIDGET_CONTROL, UVAL.ENABLE_WIDS(i), SENSITIVE=SENSE
  715. end     
  716.  
  717. ;---------------------------------------------------------------------  
  718. ;
  719. ;   PURPOSE : Change the top level base name to new file name.
  720. ;
  721. pro Change_Filename, $
  722.     UVAL, $     ; IN: uval structure
  723.     Filename    ; IN: file name (string)
  724.  
  725.     WIDGET_CONTROL, UVAL.WID_MAIN, $
  726.         TLB_SET_TITLE='WaveletTool - '+Filename
  727. end
  728.      
  729. ;---------------------------------------------------------------------  
  730. ;
  731. ;   PURPOSE : Erases original image draw widget.
  732. ;
  733. pro Erase_Original, $
  734.     UVAL     ; IN: uval structure
  735.  
  736.     WSET, UVAL.ID_ORIG
  737.     erase
  738. end     
  739.  
  740. ;---------------------------------------------------------------------  
  741. ;
  742. ;   PURPOSE : Erases original image draw widget.
  743. ;
  744. pro Erase_Secondary, $
  745.     UVAL     ; IN: uval structure
  746.  
  747.     WSET, UVAL.ID_WAVE1
  748.     erase
  749.     WSET, UVAL.ID_WAVE2
  750.     erase
  751.     WSET, UVAL.ID_PLOT
  752.     erase
  753.     No_Compressed_Image, UVAL
  754. end     
  755.      
  756. ;---------------------------------------------------------------------  
  757. ;
  758. ;   PURPOSE : Get a new data set.
  759. ;
  760. pro Data_Input, $
  761.     UVAL     ; IN: uval structure
  762.  
  763.     GetData2, NewImage, OFILENAME= file, /TWO_DIM, $
  764.         GROUP=UVAL.B_MAIN
  765.  
  766.     WIDGET_CONTROL,/hourglass            
  767.  
  768.     ;  If file is undefined, no selection     
  769.     ;
  770.     if (N_ELEMENTS(file) NE 0) then begin     
  771.  
  772.         ;  Got one, allow input to other widgets   
  773.         ;
  774.         Change_Filename, UVAL, file  
  775.  
  776.         ;  Adjust size of image to 256,256 if necessary     
  777.         ;
  778.         UVAL.ORIG_IMG = Adjust_Size (NewImage)
  779.         UVAL.FILE_LOADED = 1B
  780.         Sensitize, UVAL, 1
  781.         Erase_Original, UVAL
  782.         Erase_Secondary, UVAL
  783.         Got_New_Image, UVAL     
  784.         textChange = ['selecto','adjus', 'perce']
  785.         putTips, UVAL.sText, UVAL.wText[1], $
  786.             textChange, [0,1,2]
  787.  
  788.     endif     
  789. end     
  790.      
  791. ;---------------------------------------------------------------------  
  792. ;
  793. ;   PURPOSE : Given the wavelet basis and the setting
  794. ;             on the slider, do the compression and display it.
  795. ;
  796. pro Do_Compression, $
  797.     UVAL     ; IN: uval structure
  798.  
  799.     WIDGET_CONTROL, /HOURGLASS
  800.     WSET, UVAL.ID_COMP
  801.     erase
  802.     tmp = NR_WTN(DECIMATE (UVAL.WVLT_IMG, UVAL.THRESHOLD), $
  803.         UVAL.COEFFS, /INVERSE)
  804.  
  805.     ;  Range the value of the compressed image between 0 and 255.
  806.     ;
  807.     tmp = tmp > 0
  808.     tmp = tmp < 255
  809.  
  810.     UVAL.COMP_IMG = tmp
  811.     demo_wvlt_tv, tmp
  812.  
  813.     if (NOT(Widget_Info(UVAL.WID_DIFFBASE, /Valid_Id))) then begin
  814.         B_DIFF = WIDGET_BASE(GROUP_LEADER=UVAL.WID_MAIN, $     
  815.             COLUMN=1, MAP=0, $     
  816.             TITLE='WaveletTool Image Differences')
  817.  
  818.             D_DIFF = WIDGET_DRAW( B_DIFF, RETAIN=2, $     
  819.                 XSIZE=256, YSIZE=256, /FRAME)   
  820.  
  821.         WIDGET_CONTROL, B_DIFF, /Realize
  822.         WIDGET_CONTROL, D_DIFF, get_value=NEW_DIFF_ID
  823.         UVAL.ID_DIFF = NEW_DIFF_ID
  824.         UVAL.WID_DIFFBASE = B_DIFF
  825.     endif
  826.  
  827.     WSET, UVAL.ID_DIFF
  828.     erase
  829.     UVAL.differenceImage = bytscl((UVAL.ORIG_IMG - tmp) > 0, $
  830.        top=!d.table_size-1)
  831.     UVAL.compressImageFlag = 1
  832.     demo_wvlt_tv, UVAL.differenceImage
  833.     UVAL.COMPRESSED = 1B
  834. end     
  835.  
  836. ;---------------------------------------------------------------------  
  837. ;
  838. ;   PURPOSE : Get a new wavelet basis, clear the draw window,
  839. ;             recompute the new image (do compresssion) and
  840. ;             display that image.
  841. ;
  842. pro New_Coeff, $
  843.     UVAL, $     ; IN: uval structure
  844.     COEFF       ; IN: wavelet coeeficients
  845.  
  846.     if (COEFF NE UVAL.COEFFS) then begin
  847.         UVAL.COEFFS = COEFF
  848.  
  849.         if (UVAL.FILE_LOADED EQ 1B) then begin
  850.             textChange = ['void','comp1', 'comp2']
  851.             putTips, UVAL.sText, UVAL.wText[1], $
  852.                 textChange, [0,1,2]
  853.             Erase_Secondary, UVAL
  854.         Get_Wavelet_Basis, UVAL     
  855.             textChange = ['selecto','adjus', 'perce']
  856.             putTips, UVAL.sText, UVAL.wText[1], $
  857.                 textChange, [0,1,2]
  858.     endif      
  859.     endif
  860. end
  861.      
  862. ;---------------------------------------------------------------------  
  863. ;
  864. ;   PURPOSE : Save the compressed image.
  865. ;
  866. ;pro Do_Save, $
  867. ;    UVAL     ; IN: uval structure
  868. ;
  869. ;    file = PICKFILE(/WRITE, FILTER='*.dat', GROUP=UVAL.WID_MAIN)
  870. ;    if (file NE '')  then begin
  871. ;
  872. ;        ;  Only write if a file was selected.
  873. ;        ;
  874. ;        openw, unit, /GET_LUN, file, /XDR
  875. ;        writeu, unit, UVAL.COMP_IMG
  876. ;        free_lun, unit
  877. ;    endif
  878. ;end
  879. ;
  880. ;---------------------------------------------------------------------  
  881. ;
  882. ;   PURPOSE : Main event handler.
  883. ;
  884. pro WaveletTool_Event, $
  885.     Event               ; IN: event structure     
  886.      
  887.     if (TAG_NAMES(Event, /STRUCTURE_NAME) EQ $
  888.         'WIDGET_KILL_REQUEST') then begin
  889.         WIDGET_CONTROL, Event.top, /DESTROY
  890.         RETURN
  891.     endif
  892.  
  893.     WIDGET_CONTROL,Event.Id,GET_UVALUE=WidUvalue
  894.     WIDGET_CONTROL,Event.Top, GET_UVALUE=UVAL, /NO_COPY     
  895.        
  896.     case WidUvalue of      
  897.  
  898.         ;  Open a new file (new data set).
  899.         ;
  900.         'OPEN': begin
  901.             Data_Input, UVAL    
  902.             WIDGET_CONTROL, UVAL.B_MAIN, SENSITIVE=0
  903.             UVAL.compressImageFlag = 0
  904.  
  905.             perc = 75L
  906.             Move_Line, UVAL, perc
  907.             New_Percentage, UVAL, perc
  908.             xValue = STRING(perc, FORMAT='(f6.2)')
  909.             xValue = STRTRIM(xValue,2)
  910.             xValue = xValue + ' %'
  911.             WIDGET_CONTROL, UVAL.SliderValue, SET_VALUE=xValue
  912.             Do_Compression, UVAL     
  913.             WIDGET_CONTROL, UVAL.B_MAIN, SENSITIVE=1
  914.  
  915.             WIDGET_CONTROL, UVAL.B_MAIN, SENSITIVE=1
  916.  
  917.         end
  918.  
  919.         ;  Quit this application.
  920.         ;
  921.         'QUIT': begin
  922.             WIDGET_CONTROL,Event.Top, SET_UVALUE=UVAL, /NO_COPY     
  923.             WIDGET_CONTROL,Event.Top, /destroy     
  924.  
  925.             ;  Return after this!     
  926.             ;
  927.             return     
  928.         end
  929.                             
  930.         ;  Compute the wavelet transform with 4 coefficients.
  931.         ;
  932.         'FOUR': begin
  933.             WIDGET_CONTROL, UVAL.B_MAIN, SENSITIVE=0
  934.             WIDGET_CONTROL, UVAL.wFourButton, SENSITIVE=0
  935.             WIDGET_CONTROL, UVAL.wTwelveButton, SENSITIVE=1
  936.             WIDGET_CONTROL, UVAL.wTwentyButton, SENSITIVE=1
  937.             New_Coeff, UVAL, 4
  938.             Do_Compression, UVAL     
  939.             WIDGET_CONTROL, UVAL.SliderValue, SET_VALUE='000.00%'
  940.             WIDGET_CONTROL, UVAL.B_MAIN, SENSITIVE=1
  941.         end
  942.                         
  943.         ;  Compute the wavelet transform with 12 coefficients.
  944.         ;
  945.         'TWELVE': begin
  946.             WIDGET_CONTROL, UVAL.B_MAIN, SENSITIVE=0
  947.             WIDGET_CONTROL, UVAL.wFourButton, SENSITIVE=1
  948.             WIDGET_CONTROL, UVAL.wTwelveButton, SENSITIVE=0
  949.             WIDGET_CONTROL, UVAL.wTwentyButton, SENSITIVE=1
  950.             New_Coeff, UVAL, 12
  951.             WIDGET_CONTROL, UVAL.SliderValue, SET_VALUE='000.00%'
  952.             Do_Compression, UVAL     
  953.             WIDGET_CONTROL, UVAL.B_MAIN, SENSITIVE=1
  954.         end
  955.                                 
  956.         ;  Compute the wavelet transform with 20 coefficients.
  957.         ;
  958.         'TWENTY': begin
  959.             WIDGET_CONTROL, UVAL.B_MAIN, SENSITIVE=0
  960.             WIDGET_CONTROL, UVAL.wFourButton, SENSITIVE=1
  961.             WIDGET_CONTROL, UVAL.wTwelveButton, SENSITIVE=1
  962.             WIDGET_CONTROL, UVAL.wTwentyButton, SENSITIVE=0
  963.             New_Coeff, UVAL, 20
  964.             Do_Compression, UVAL     
  965.             WIDGET_CONTROL, UVAL.SliderValue, SET_VALUE='000.00%'
  966.             WIDGET_CONTROL, UVAL.B_MAIN, SENSITIVE=1
  967.         end
  968.                                 
  969.         ;  Show the difference between the original and the
  970.         ;  compressed image.
  971.         ;
  972.         'DIFFERENCE': begin
  973.             if (UVAL.compressImageFlag eq 1) then begin
  974.                 if not(Widget_Info(UVAL.WID_DIFFBASE, $
  975.                     /Valid_Id)) then begin
  976.  
  977.                     B_DIFF = WIDGET_BASE(GROUP_LEADER= $
  978.                         UVAL.WID_MAIN, $     
  979.                         COLUMN=1, MAP=0, $     
  980.                         TITLE='WaveletTool Image Differences')
  981.  
  982.                     D_DIFF = WIDGET_DRAW( B_DIFF, $     
  983.                         RETAIN=2, XSIZE=256, YSIZE=256, /FRAME)   
  984.  
  985.                     WIDGET_CONTROL, B_DIFF, /REALIZE
  986.                     WIDGET_CONTROL, D_DIFF, get_value=NEW_DIFF_ID
  987.                     UVAL.ID_DIFF = NEW_DIFF_ID
  988.                     UVAL.WID_DIFFBASE = B_DIFF
  989.                     WSET, NEW_DIFF_ID
  990.                     demo_wvlt_tv, UVAL.differenceImage
  991.                 endif
  992.  
  993.                 ;  Map the showdiff base
  994.                 ;
  995.                 WIDGET_CONTROL, UVAL.WID_DIFFBASE, MAP=1
  996.                 WIDGET_CONTROL, UVAL.WID_DIFFBASE, /SHOW
  997.             endif
  998.         end    
  999.                             
  1000.         ;  Load a new color table.
  1001.         ;
  1002.         'XLOADCT': begin
  1003.             WIDGET_CONTROL,Event.Top, SET_UVALUE=UVAL, /NO_COPY     
  1004.             WIDGET_CONTROL,/hourglass
  1005.             XLoadct, GROUP=Event.top
  1006.             RETURN
  1007.         end
  1008.                                 
  1009.         ;  Display the information text.
  1010.         ;
  1011.         'ABOUT': begin 
  1012.             if (Xregistered('XDisplayFile') ne 0) then begin
  1013.                 WIDGET_CONTROL,Event.Top, SET_UVALUE=UVAL, /NO_COPY     
  1014.                 RETURN
  1015.             endif
  1016.  
  1017.             ;  Display the information.
  1018.             ;
  1019.             XDisplayFile, filepath("wavelet.txt", $
  1020.                 SUBDIR=['examples','demo','demotext']), $
  1021.                 DONE_BUTTON='Done', $
  1022.                 TITLE="Wavelet tool help", $
  1023.                 GROUP=Event.top, WIDTH=55, HEIGHT=14
  1024.         end    ;   of ABOUT
  1025.  
  1026.  
  1027.                      
  1028.         ;  Handle the compression slider event. Redo all the plots.
  1029.         ;
  1030.         'S_COMPRESSED': begin     
  1031.  
  1032.             ;  Need to clear the comp image draw
  1033.             ;  we are guarranteed no drag events
  1034.             ;
  1035.             WIDGET_CONTROL, UVAL.B_MAIN, SENSITIVE=0
  1036.             Move_Line, UVAL, Event.value
  1037.             New_Percentage, UVAL, Event.value
  1038.             xValue = STRING(Event.value, FORMAT='(f6.2)')
  1039.             xValue = STRTRIM(xValue,2)
  1040.             xValue = xValue + ' %'
  1041.             WIDGET_CONTROL, UVAL.SliderValue, SET_VALUE=xValue
  1042.             Do_Compression, UVAL     
  1043.             WIDGET_CONTROL, UVAL.B_MAIN, SENSITIVE=1
  1044.         END          
  1045.  
  1046.         ;  Handle the compression plot drawing event.
  1047.         ;
  1048.         'D_PLOT': begin     
  1049.  
  1050.             CASE Event.Type of
  1051.  
  1052.                 0: begin
  1053.  
  1054.                     ;  Button press
  1055.                     ;  check which button (only left buttton is active)
  1056.                     ;
  1057.                     if (Event.Press EQ 1) then begin
  1058.  
  1059.                         ;  Start the drag process
  1060.                         ;
  1061.                         UVAL.DRAGGING = 1B
  1062.  
  1063.                         ;  Draw the first line
  1064.                         ;
  1065.                         WSET, UVAL.ID_PLOT
  1066.                         tmp = Convert_coord(Event.X,0,/device,/to_data)
  1067.                         tmp(0)= IN_RANGE (tmp(0), 0, 100)
  1068.                         Move_Line, UVAL, tmp(0)
  1069.                         UVAL.PERCENTAGE = tmp(0)
  1070.                     endif
  1071.                 END                   ;   of 0
  1072.                             
  1073.                 1: begin
  1074.  
  1075.                     ;  Button release
  1076.                     ;  check which button (only act on left)
  1077.                     ;
  1078.                     if (Event.Release EQ 1) then begin
  1079.  
  1080.                         ;  Stop the dragging
  1081.                         ;
  1082.                         UVAL.DRAGGING = 0B
  1083.  
  1084.                         ;  Evaluate percentage and update slider, etc.
  1085.                         ;  need to clear the comp image draw
  1086.                         ;
  1087.                         WSET, UVAL.ID_PLOT
  1088.                         tmp = Convert_coord(Event.X,0,/device,/to_data)
  1089.                         tmp(0)= IN_RANGE (tmp(0), 0, 100)
  1090.                         Move_Line, UVAL, tmp(0)
  1091.                         New_Percentage, UVAL, tmp(0)
  1092.                         Do_Compression, UVAL     
  1093.                     endif
  1094.                 END                   ;   of 1
  1095.                             
  1096.                 2: begin
  1097.  
  1098.                     ;  Motion event.
  1099.                     ;  Check if dragging.
  1100.                     ;
  1101.                     if (UVAL.DRAGGING EQ 1B) then begin
  1102.  
  1103.                         ;  Draw new line (xor'd)
  1104.                         ;
  1105.                         WSET, UVAL.ID_PLOT
  1106.                         tmp = Convert_coord(Event.X,0,/device,/to_data)
  1107.                         tmp(0)= IN_RANGE (tmp(0), 0, 100)
  1108.                         Move_Line, UVAL, tmp(0)
  1109.                         UVAL.PERCENTAGE=tmp(0)
  1110.                     endif
  1111.                 END            ;   of 2
  1112.                             
  1113.                 ELSE:
  1114.  
  1115.             endcase
  1116.         END          
  1117.                      
  1118.         ELSE:      ;   do nothing
  1119.                      
  1120.     endcase     
  1121.              
  1122.     WIDGET_CONTROL, Event.Top, SET_UVALUE=UVAL, /NO_COPY     
  1123.      
  1124. end    
  1125.  
  1126. ;---------------------------------------------------------------------  
  1127. ;
  1128. ;   PURPOSE : Cleanup procedure.
  1129. ;
  1130. pro Wavelet_Cleanup, tlb
  1131.  
  1132.     ;  Get the color table saved in the window's user value.
  1133.     ;
  1134.     WIDGET_CONTROL, tlb, GET_UVALUE=UVAL, /NO_COPY
  1135.  
  1136.     ;  Restore the previous color table.
  1137.     ;
  1138.     TVLCT, UVAL.colorTable
  1139.  
  1140.     if widget_info(UVAL.groupBase, /valid) then $
  1141.         WIDGET_CONTROL, UVAL.groupBase, /map
  1142.  
  1143. end  ; Of Wavelet_Cleanup
  1144.      
  1145. ;---------------------------------------------------------------------  
  1146. ;
  1147. ;   PURPOSE :  Transform an image using the orthogonal
  1148. ;              wavelet method (Daubechies coefficients).
  1149. ;
  1150. pro D_Wavelet, $
  1151.     GROUP=group, $     ; IN: (opt) group identifier
  1152.     APPTLB = appTLB    ; OUT: (opt) TLB of this application
  1153.  
  1154.     ;  Check the validity of the group identifier.
  1155.     ;
  1156.     ngroup = N_ELEMENTS(group)
  1157.     if (ngroup NE 0) then begin
  1158.         check = widget_INFO(group, /valid)
  1159.         if (check NE 1) then begin
  1160.             print,'Error, the group identifier is not valid'
  1161.             print, 'Return to the main application'
  1162.             RETURN
  1163.         endif
  1164.         groupBase = group
  1165.     endif else groupBase = 0L
  1166.  
  1167.      
  1168.     CHARSIZE = 6.0 / !D.X_CH_SIZE
  1169.  
  1170.     ;  Get the screeen size.
  1171.     ;
  1172.     device, GET_SCREEN_SIZE=scr
  1173.  
  1174.     myScroll = 0   ; For adding scroll bars if necessary
  1175.     if (scr(0) LT 1000) then begin
  1176.         void =  $
  1177.         WIDGET_MESSAGE('This application is optimized for 1024 x 768 resolution') 
  1178.         myScroll = 1  ; Add the scroll bar when creating the TLB
  1179.     endif
  1180.  
  1181.  
  1182.     ;  Get the screen size and set an offset..
  1183.     ;
  1184.     Device, GET_SCREEN_SIZE = scrsize
  1185.  
  1186.     ;  Create the starting up message.
  1187.     ;
  1188.     if (ngroup EQ 0) then begin
  1189.         drawbase = startmes()
  1190.     endif else begin
  1191.         drawbase = startmes(GROUP=group)
  1192.     endelse
  1193.  
  1194.     xdimImage = 256
  1195.     ydimImage = 256
  1196.     xdimBasis = 256
  1197.     ydimBasis = 256
  1198.     xdimPlot = 256
  1199.     ydimPlot = 256
  1200.  
  1201.     ;  Save the current color table.
  1202.     ;
  1203.     TVLCT, savedR, savedG, savedB,/GET
  1204.     colorTable=[[savedR], [savedG], [savedB]]
  1205.  
  1206.     ;  Load an new color table.
  1207.     ;
  1208.     LOADCT, 0
  1209.  
  1210.     junk   = { CW_PDMENU_S, flags:0, name:'' }     
  1211.  
  1212.     ;  Get the tips.
  1213.     ;
  1214.     sText = getTips(filepath('wavelet.tip', $
  1215.         SUBDIR=['examples','demo', 'demotext']) )
  1216.                               
  1217.     ;  Create the widget hierarchy starting with the
  1218.     ;  top level base.
  1219.     ;
  1220.     if (myScroll EQ 1) then begin
  1221.         if (N_ELEMENTS(group) EQ 0) then begin
  1222.             B_MAIN = WIDGET_BASE( $
  1223.                 TLB_FRAME_ATTR=1, $
  1224.                 SCROLL=myScroll, $
  1225.                 X_SCROLL_SIZE=scrsize[0]-75, Y_SCROLL_SIZE=scrsize[1]-75, $
  1226.                 /TLB_KILL_REQUEST_EVENTS, $
  1227.                 COLUMN=1, MAP=0, MBAR=barBase, TITLE='WaveletTool')     
  1228.         endif else begin
  1229.             B_MAIN = WIDGET_BASE(GROUP_LEADER=group, $     
  1230.                 TLB_FRAME_ATTR=1, $
  1231.                 SCROLL=myScroll, $
  1232.                 X_SCROLL_SIZE=scrsize[0]-75, Y_SCROLL_SIZE=scrsize[1]-75, $
  1233.                 /TLB_KILL_REQUEST_EVENTS, $
  1234.                 COLUMN=1, MAP=0, MBAR=barBase, TITLE='WaveletTool')     
  1235.         endelse
  1236.     endif else begin
  1237.         if (N_ELEMENTS(group) EQ 0) then begin
  1238.             B_MAIN = WIDGET_BASE( $
  1239.                 TLB_FRAME_ATTR=1, $
  1240.                 /TLB_KILL_REQUEST_EVENTS, $
  1241.                 COLUMN=1, MAP=0, MBAR=barBase, TITLE='WaveletTool')     
  1242.         endif else begin
  1243.             B_MAIN = WIDGET_BASE(GROUP_LEADER=group, $     
  1244.                 TLB_FRAME_ATTR=1, $
  1245.                 /TLB_KILL_REQUEST_EVENTS, $
  1246.                 COLUMN=1, MAP=0, MBAR=barBase, TITLE='WaveletTool')     
  1247.         endelse
  1248.     endelse
  1249.  
  1250.         ;  Create the file menu.
  1251.         ;
  1252.         wFileButton = WIDGET_BUTTON(barbase, VALUE='File', /MENU)
  1253.  
  1254.             wOpenButton = WIDGET_BUTTON(wFileButton, $
  1255.                 VALUE='Open', UVALUE='OPEN')
  1256.  
  1257.             wQuitButton = WIDGET_BUTTON(wFileButton, $
  1258.                 VALUE='Quit', UVALUE='QUIT')
  1259.  
  1260.         ;  Create the option menu.
  1261.         ;
  1262.         wOptionButton = WIDGET_BUTTON(barbase, VALUE='Options', /MENU)
  1263.  
  1264.             wFourButton = WIDGET_BUTTON(wOptionButton, $
  1265.                 VALUE='4 Coefficients', UVALUE='FOUR')
  1266.  
  1267.             wTwelveButton = WIDGET_BUTTON(wOptionButton, $
  1268.                 VALUE='12 Coefficients', UVALUE='TWELVE')
  1269.  
  1270.             wTwentyButton = WIDGET_BUTTON(wOptionButton, $
  1271.                 VALUE='20 Coefficients', UVALUE='TWENTY')
  1272.  
  1273.             wDifferenceButton = WIDGET_BUTTON(wOptionButton, $
  1274.                 VALUE='Show Difference Image', UVALUE='DIFFERENCE')
  1275.  
  1276.         ;  Create the tool menu.
  1277.         ;
  1278.         wViewButton = WIDGET_BUTTON(barbase, VALUE='View', /MENU)
  1279.  
  1280.             wXLoadctButton = WIDGET_BUTTON(wViewButton, $
  1281.                 VALUE='Color Palette', UVALUE='XLOADCT')
  1282.  
  1283.         ;  Create the Help/About button.
  1284.         ;
  1285.         wHelpButton = WIDGET_BUTTON(barbase, /HELP, Value = 'About',/Menu)
  1286.  
  1287.             wAboutButton = WIDGET_BUTTON(wHelpButton, $
  1288.                 VALUE='About Wavelets', UVALUE='ABOUT')
  1289.  
  1290.         B_ALLDISP = WIDGET_BASE(B_MAIN, ROW=1, SPACE=5, XPAD=5, YPAD=5, $     
  1291.             FRAME=1, MAP=1, TITLE='ALL Display', UVALUE='B_ALLDISP')     
  1292.                                          
  1293.             ;  B_DISPLAY is the base that contains the original 
  1294.             ;  and compressed images.
  1295.             ;
  1296.             B_DISPLAY = WIDGET_BASE(B_ALLDISP, /COLUMN, SPACE=5, $     
  1297.             XPAD=5, YPAD=5, FRAME=1, MAP=1, TITLE='Display', $     
  1298.                 UVALUE='B_DISPLAY', /BASE_ALIGN_CENTER)     
  1299.      
  1300.                 B_ORIGINAL = WIDGET_BASE(B_DISPLAY, COLUMN=1, MAP=1, $     
  1301.                     TITLE='original_base', UVALUE='B_ORIGINAL')     
  1302.      
  1303.                     L_ORIGINAL = WIDGET_LABEL( B_ORIGINAL, $     
  1304.                         UVALUE='L_ORIGINAL', VALUE='Original:')     
  1305.      
  1306.                     D_ORIGINAL = WIDGET_DRAW( B_ORIGINAL, $     
  1307.                         RETAIN=2, UVALUE='D_ORIGINAL', $     
  1308.                         XSIZE=256, YSIZE=256, /FRAME)     
  1309.      
  1310.                 B_COMPRESSED = WIDGET_BASE(B_DISPLAY, COLUMN=1, $     
  1311.                     MAP=1, TITLE='compressed_base', $     
  1312.                     UVALUE='B_COMPRESSED')     
  1313.      
  1314.                     L_COMPRESSED = WIDGET_LABEL( B_COMPRESSED, $     
  1315.                         UVALUE='L_COMPRESSED', VALUE='Compressed:')     
  1316.      
  1317.                     D_COMPRESSED = WIDGET_DRAW( B_COMPRESSED, $     
  1318.                         RETAIN=2, UVALUE='D_COMPRESSED', $     
  1319.                         XSIZE=256, YSIZE=256, /FRAME)     
  1320.  
  1321.             ;  B_WAVEADJ is the base that contains our interface 
  1322.             ;  to adjust the compression amount of our wavelet basis.
  1323.             ;
  1324.             B_WAVES = WIDGET_BASE(B_ALLDISP, COLUMN=1, SPACE=5, $     
  1325.                 XPAD=5, YPAD=5, FRAME=1, MAP=1, $     
  1326.                 TITLE='Wavelets', UVALUE='B_WAVES')     
  1327.                                  
  1328.                 L_WAVES = WIDGET_LABEL( B_WAVES, $     
  1329.                     UVALUE='L_WAVES', VALUE='Wavelet Basis:')     
  1330.      
  1331.                 B_WAVEADJ = WIDGET_BASE(B_WAVES, ROW=1, SPACE=10, $     
  1332.                     XPAD=10, YPAD=10, FRAME=0, MAP=1, $     
  1333.                     TITLE='Wavelet Adjust', UVALUE='B_WAVEADJ')     
  1334.                                  
  1335.                     ;  Base to hold tv's of wavelet basis.
  1336.                     ;
  1337.                     B_SHOWIMAGE1 = WIDGET_BASE(B_WAVEADJ, $     
  1338.                         /COLUMN, MAP=1, TITLE='show wavelet images', $     
  1339.                         UVALUE='B_SHOWIMAGE1')     
  1340.  
  1341.                         L_WAVE1 = WIDGET_LABEL( B_SHOWIMAGE1, $     
  1342.                             UVALUE='L_WAVE1', VALUE='Original:')     
  1343.                          
  1344.                         D_WAVE1 = WIDGET_DRAW( B_SHOWIMAGE1, $     
  1345.                             RETAIN=2, UVALUE='D_WAVE1', $
  1346.                             XSIZE=200, YSIZE=200, /FRAME)
  1347.  
  1348.                     B_SHOWIMAGE2 = WIDGET_BASE(B_WAVEADJ, $     
  1349.                         /COLUMN, MAP=1, TITLE='show wavelet images', $     
  1350.                         UVALUE='B_SHOWIMAGE2')     
  1351.  
  1352.                         L_WAVE2 = WIDGET_LABEL( B_SHOWIMAGE2, $     
  1353.                             UVALUE='L_WAVE2', VALUE='Compressed:')     
  1354.  
  1355.                         D_WAVE2 = WIDGET_DRAW( B_SHOWIMAGE2, $     
  1356.                             RETAIN=2, UVALUE='D_WAVE2', $     
  1357.                             XSIZE=200, YSIZE=200, /FRAME)
  1358.  
  1359.                 ;  Base to hold plot and slider for adjusting compression.
  1360.                 ;
  1361.                 B_ADJCOMP = WIDGET_BASE(B_WAVES, $     
  1362.                     COLUMN=1, MAP=1, FRAME=0, SPACE=10, $     
  1363.                     XPAD=10, YPAD=10, TITLE='adjust compression', $     
  1364.                     UVALUE='B_ADJCOMP')     
  1365.                                                  
  1366.                     L_ADJCOMP = WIDGET_LABEL( B_ADJCOMP, $     
  1367.                         UVALUE='L_ADJCOMP', VALUE='Adjust Compression:')     
  1368.  
  1369.                     D_PLOT = WIDGET_DRAW( B_ADJCOMP, RETAIN=2, $     
  1370.                         UVALUE='D_PLOT', $     
  1371.                         XSIZE=420, YSIZE=200, /FRAME, $
  1372.                         /MOTION_EVENTS, /BUTTON_EVENTS)     
  1373.  
  1374.                     SliderValue = WIDGET_LABEL(B_ADJCOMP, $ 
  1375.                         VALUE='  75.00 %', /ALIGN_CENTER)
  1376.  
  1377.                     S_COMPRESSED = WIDGET_SLIDER( B_ADJCOMP, $     
  1378.                         MAXIMUM=100, XSIZE=420, $
  1379.                         TITLE='Percentage Compression', $     
  1380.                         UVALUE='S_COMPRESSED', $     
  1381.             VALUE=75, /SUPPRESS_VALUE)
  1382.  
  1383.         ;  Create the status line label.
  1384.         ;
  1385.         wStatusBase = WIDGET_BASE(B_MAIN, MAP=0, /ROW)
  1386.  
  1387.             nWidgets = 2
  1388.             wText = LONARR(nWidgets)
  1389.             widTips, wStatusBase, sText.text, XSIZE=36, $
  1390.                 YSIZE=3, NWIDGETS=nWidgets, wText
  1391.  
  1392.         ;  We have a second top-level base to show differences.
  1393.         ;
  1394.         B_DIFF = WIDGET_BASE(GROUP_LEADER=B_MAIN, COLUMN=1, $     
  1395.             MAP=0, TITLE='WaveletTool Image Differences')
  1396.      
  1397.             D_DIFF = WIDGET_DRAW( B_DIFF, RETAIN=2, $     
  1398.             XSIZE=256, YSIZE=256, /FRAME)   
  1399.             
  1400.     WIDGET_CONTROL, B_MAIN, /REALIZE     
  1401.     WIDGET_CONTROL, B_DIFF, MAP=0, /REALIZE
  1402.  
  1403.     ; Returns the top level base to the APPTLB keyword.
  1404.     ;
  1405.     appTLB = B_MAIN
  1406.  
  1407.     ;  Size the tips widgets.
  1408.     ;
  1409.     sizeTips, B_MAIN, wText, wStatusBase
  1410.  
  1411.  
  1412.     UVAL = {ID_ORIG:0L, $                ; Windows IDs, original
  1413.             ID_COMP:0L, $                ;              compressed 
  1414.             ID_WAVE1:0L, $               ;              wavelet 1
  1415.             ID_WAVE2:0L, $               ;              wavelet 2
  1416.             ID_PLOT:0L, $                ;              pecentage plot
  1417.             ID_DIFF:0L, $                ;              difference image
  1418.             B_MAIN: B_MAIN, $            ; Top level base
  1419.             WID_STATUS:0L, $             ; Status label ID
  1420.             WID_SLIDER:0L, $             ; Percentage slider ID
  1421.             WID_DIFFBASE:0L, $           ; Difference image base ID
  1422.             WID_MAIN:0L, $               ; Main base ID
  1423.             WID_COEFFS:0L, $             ; Number of coefficients button IDs
  1424.             ENABLE_WIDS:LONARR(8), $     ; Enabled widgets IDs (see list below)
  1425.             THRESHOLD: 0.0, $            ; Threshold value
  1426.             COEFFS:0, $                  ; Number of wavelets coefficients
  1427.             FILE_LOADED:0B, $            ; File loaded flag
  1428.             PERCENTAGE:0.0, $            ; Compression precentage value
  1429.             DRAGGING:0B, $               ; Dragging mode:0=not, 1=yes
  1430.             WFourButton: wFourButton, $  ; Widget button IDs
  1431.             WTwelveButton: wTwelveButton, $
  1432.             WTwentyButton: wTwentyButton, $
  1433.             DifferenceImage:  $
  1434.             BYTARR(xdimImage, yDimImage), $ ; Difference image
  1435.             SliderValue: SliderValue, $  ; Percentage slider value
  1436.             CompressImageFlag : 0, $     ; 0= not drawn, 1=drawn
  1437.             ColorTable: colorTable, $    ; Color table to restore
  1438.             CHARSIZE: CHARSIZE, $
  1439.             WText: wText, $              ; Widget text IDs for tips
  1440.             SText: sText, $              ; Text structure for tips
  1441.             ;  Set this to 1 to start to force erase of ID_COMP
  1442.             COMPRESSED:1B, $             ; Compress flag
  1443.             THRESHARRAY:FLTARR(1001), $  ; Threshold array
  1444.             ORIG_IMG:BYTARR(256,256), $  ; Original image
  1445.             WVLT_IMG:FLTARR(256,256), $  ; Wavelet image
  1446.             COMP_IMG:BYTARR(256,256), $  ; Compressed image
  1447.             groupBase: groupBase $       ; Base of Group Leader
  1448.     }
  1449.                 
  1450.  
  1451.     ;  The ENABLE_WIDS array is an array of widget ids 
  1452.     ;  to desensitize when there
  1453.     ;  is no filename selected.
  1454.      
  1455.     ;  Fill the UVALUE structure of our main base with our values.
  1456.     ;
  1457.     WIDGET_CONTROL, D_ORIGINAL, GET_VALUE=originalValue
  1458.     UVAL.ID_ORIG = originalValue     
  1459.     WIDGET_CONTROL, D_COMPRESSED, GET_VALUE=compressedValue
  1460.     UVAL.ID_COMP = compressedValue   
  1461.     WIDGET_CONTROL, D_WAVE1, GET_VALUE=wave1Value     
  1462.     UVAL.ID_WAVE1 = wave1Value
  1463.     WIDGET_CONTROL, D_WAVE2, GET_VALUE=wave2Value     
  1464.     UVAL.ID_WAVE2 = wave2Value
  1465.     WIDGET_CONTROL, D_PLOT, GET_VALUE=differenceValue     
  1466.     UVAL.ID_PLOT = differenceValue
  1467.     WIDGET_CONTROL, D_DIFF, GET_VALUE=differenceValue     
  1468.     UVAL.ID_DIFF = differenceValue
  1469.     UVAL.WID_SLIDER = S_COMPRESSED        
  1470.     UVAL.WID_DIFFBASE = B_DIFF
  1471.     UVAL.WID_MAIN = B_MAIN
  1472.     UVAL.ENABLE_WIDS = $
  1473.         [L_COMPRESSED, L_WAVE1, L_WAVE2, L_ADJCOMP, L_ORIGINAL, $
  1474.     L_WAVES, S_COMPRESSED, D_PLOT]
  1475.     
  1476.     ;  Set up initial parameters.
  1477.     ;  Clean up the windows.
  1478.     ;
  1479.     New_Coeff, UVAL, 4
  1480.     Erase_Original, UVAL
  1481.     Erase_Secondary, UVAL
  1482.     Sensitize, UVAL, 0
  1483.     textChange = ['sele1', 'sele2']
  1484.     putTips, UVAL.sText, UVAL.wText[1], $
  1485.         textChange, [1,2]
  1486.     Change_Filename, UVAL, '<NONE>'
  1487.         
  1488.  
  1489.     ;  Load an initial file .
  1490.     ;
  1491.     file = 'ctscan.dat'
  1492.     GetData2, NewImage, FILENAME=file, /TWO_DIM     
  1493.     Change_Filename, UVAL, file
  1494.  
  1495.     ;  Adjust size of image to 256,256 if necessary.
  1496.     ;
  1497.     UVAL.ORIG_IMG = Adjust_Size (NewImage)
  1498.     UVAL.FILE_LOADED = 1B
  1499.     Sensitize, UVAL, 1
  1500.     Erase_Original, UVAL
  1501.     Erase_Secondary, UVAL
  1502.     Got_New_Image, UVAL
  1503.     textChange = ['selecto','adjus', 'perce']
  1504.     putTips, UVAL.sText, UVAL.wText[1], $
  1505.         textChange, [0,1,2]
  1506.  
  1507.     WIDGET_CONTROL, B_MAIN, SET_UVALUE=UVAL      
  1508.     WIDGET_CONTROL, wFourButton, SENSITIVE=0
  1509.       
  1510.     ;  Destroy the starting up window.
  1511.     ;
  1512.     WIDGET_CONTROL, drawbase, /DESTROY
  1513.  
  1514.     ;  Map the top level base.
  1515.     ;
  1516.     WIDGET_CONTROL, B_MAIN, MAP=1
  1517.  
  1518.     ;  Set up the default percentage value to 75 %.
  1519.     ;
  1520.     pseudoEvent = { $
  1521.         ID: S_COMPRESSED, $
  1522.         TOP: B_MAIN, $
  1523.         HANDLER: B_MAIN, $
  1524.         VALUE:75L, $
  1525.         DRAG:0 $
  1526.     }
  1527.     WaveletTool_Event, pseudoEvent
  1528.  
  1529.     ;  Map the top level base.
  1530.     ;
  1531.     WIDGET_CONTROL, B_MAIN, MAP=1
  1532.  
  1533.     XMANAGER, 'D_Wavelet', B_MAIN, $
  1534.         EVENT_HANDLER='WaveletTool_Event', CLEANUP='Wavelet_Cleanup', $
  1535.         /NO_BLOCK
  1536.  
  1537. end  ;    of d_wavelet     
  1538.